import org.gradle.initialization.DependenciesAccessors
import org.gradle.kotlin.dsl.support.serviceOf

plugins {
    `kotlin-dsl`
}

dependencies {
    compileOnly(libs.android.gradlePlugin)
    compileOnly(libs.kotlin.gradlePlugin)
    gradle.serviceOf<DependenciesAccessors>().classes.asFiles.forEach {
        compileOnly(files(it.absolutePath))
    }
}

tasks {
    validatePlugins {
        enableStricterValidation = true
        failOnWarning = true
    }
}

group = "com.rtbishop.look4sat.build_logic.convention"

gradlePlugin {
    plugins {
        register("androidAppPlugin") {
            id = libs.plugins.convention.androidAppPlugin.get().pluginId
            implementationClass = "com.rtbishop.look4sat.convention.AndroidAppPlugin"
        }
        register("androidLibraryPlugin") {
            id = libs.plugins.convention.androidLibraryPlugin.get().pluginId
            implementationClass = "com.rtbishop.look4sat.convention.AndroidLibraryPlugin"
        }
        register("composeFeaturePlugin") {
            id = libs.plugins.convention.composeFeaturePlugin.get().pluginId
            implementationClass = "com.rtbishop.look4sat.convention.ComposeFeaturePlugin"
        }
        register("composeLibraryPlugin") {
            id = libs.plugins.convention.composeLibraryPlugin.get().pluginId
            implementationClass = "com.rtbishop.look4sat.convention.ComposeLibraryPlugin"
        }
        register("kotlinLibraryPlugin") {
            id = libs.plugins.convention.kotlinLibraryPlugin.get().pluginId
            implementationClass = "com.rtbishop.look4sat.convention.KotlinLibraryPlugin"
        }
    }
}