plugins {
    id "com.android.application"
    id "org.jetbrains.kotlin.android"
    id "org.jetbrains.kotlin.kapt"
    id "dagger.hilt.android.plugin"
}

android {
    namespace 'com.rtbishop.look4sat'
    compileSdk 33

    defaultConfig {
        applicationId "com.rtbishop.look4sat"
        minSdk 21
        targetSdk 33
        versionCode 312
        versionName '3.1.2'

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables {
            useSupportLibrary true
        }
        kapt {
            arguments {
                arg("room.schemaLocation", "$projectDir/schemas")
                arg("room.incremental", "true")
                arg("room.expandProjection", "true")
            }
            correctErrorTypes true
        }
    }
    buildFeatures {
        compose true
    }
    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_11
        targetCompatibility JavaVersion.VERSION_11
    }
    composeOptions {
        kotlinCompilerExtensionVersion compose_compiler_version
    }
    kotlinOptions {
        jvmTarget = JavaVersion.VERSION_11.toString()
    }
    packagingOptions {
        resources {
            excludes += '/META-INF/{AL2.0,LGPL2.1}'
        }
    }
    testOptions {
        animationsDisabled true
        unitTests.includeAndroidResources true
    }
}

kotlin {
    jvmToolchain(11)
}

dependencies {
    implementation project(":base")
    // Android
    implementation "androidx.core:core-splashscreen:$splashscreen_version"
    implementation "androidx.room:room-runtime:$room_version"
    implementation "androidx.room:room-ktx:$room_version"
    kapt "androidx.room:room-compiler:$room_version"
    implementation "com.google.dagger:hilt-android:$hilt_android_version"
    kapt "com.google.dagger:hilt-compiler:$hilt_android_version"
    // Compose
    implementation "androidx.activity:activity-compose:$activity_compose_version"
    implementation "androidx.compose.animation:animation:$compose_version"
    implementation "androidx.compose.compiler:compiler:$compose_compiler_version"
    implementation "androidx.compose.material3:material3:$material3_version"
    implementation "androidx.compose.runtime:runtime:$compose_version"
    implementation "androidx.compose.ui:ui:$compose_version"
    implementation "androidx.compose.ui:ui-tooling-preview:$compose_version"
    implementation "androidx.hilt:hilt-navigation-compose:$hilt_compose_version"
    implementation "androidx.lifecycle:lifecycle-viewmodel-compose:$lifecycle_version"
    implementation "androidx.navigation:navigation-compose:$navigation_version"
    // Utility
    implementation "com.jakewharton.timber:timber:$timber_version"
    implementation "org.osmdroid:osmdroid-android:$osmdroid_version"
    debugImplementation "androidx.compose.ui:ui-tooling:$compose_version"
    debugImplementation "androidx.compose.ui:ui-test-manifest:$compose_version"
    debugImplementation "com.squareup.leakcanary:leakcanary-android:$leakcanary_version"
    // Test
    testImplementation "junit:junit:$junit_version"
    testImplementation "org.mockito:mockito-core:$mockito_version"
    testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$coroutines_test_version"
    androidTestImplementation "androidx.compose.ui:ui-test-junit4:$compose_version"
    androidTestImplementation "org.mockito:mockito-android:$mockito_version"
}